diff --git a/manifests/init.pp b/manifests/init.pp
index 657038b..6e0c3c7 100644
--- a/manifests/init.pp
+++ b/manifests/init.pp
@@ -1,79 +1,77 @@
 class unattended_upgrades (
   Unattended_upgrades::Age                  $age                  = {},
   Unattended_upgrades::Auto                 $auto                 = {},
   Unattended_upgrades::Backup               $backup               = {},
   Array[String[1]]                          $blacklist            = [],
   Optional[Integer[0]]                      $dl_limit             = undef,
   Integer[0, 1]                             $enable               = 1,
   Boolean                                   $install_on_shutdown  = false,
   Boolean                                   $legacy_origin        = $unattended_upgrades::params::legacy_origin,
   Unattended_upgrades::Mail                 $mail                 = {},
   Boolean                                   $minimal_steps        = true,
   Array[String[1]]                          $origins              = $unattended_upgrades::params::origins,
   String[1]                                 $package_ensure       = installed,
   Array[String[1]]                          $extra_origins        = [],
   Optional[Integer[0]]                      $random_sleep         = undef,
   Optional[String]                          $sender               = undef,
   Integer[0]                                $size                 = 0,
   Integer[0]                                $update               = 1,
   Integer[0]                                $upgrade              = 1,
   Unattended_upgrades::Upgradeable_packages $upgradeable_packages = {},
   Integer[0]                                $verbose              = 0,
   Boolean                                   $notify_update        = false,
   Unattended_upgrades::Options              $options              = {},
   Array[String[1]]                          $days                 = [],
 ) inherits ::unattended_upgrades::params {
-
   # apt::conf settings require the apt class to work
   include apt
 
   $_age = merge($unattended_upgrades::default_age, $age)
   assert_type(Unattended_upgrades::Age, $_age)
 
   $_auto = merge($unattended_upgrades::default_auto, $auto)
   assert_type(Unattended_upgrades::Auto, $_auto)
 
   $_backup = merge($unattended_upgrades::default_backup, $backup)
   assert_type(Unattended_upgrades::Backup, $_backup)
 
   $_mail = merge($unattended_upgrades::default_mail, $mail)
   assert_type(Unattended_upgrades::Mail, $_mail)
 
   $_upgradeable_packages = merge($unattended_upgrades::default_upgradeable_packages, $upgradeable_packages)
   assert_type(Unattended_upgrades::Upgradeable_packages, $_upgradeable_packages)
 
   $_options = merge($unattended_upgrades::default_options, $options)
   assert_type(Unattended_upgrades::Options, $_options)
 
   package { 'unattended-upgrades':
     ensure => $package_ensure,
   }
 
   apt::conf { 'unattended-upgrades':
     priority      => 50,
     content       => template("${module_name}/unattended-upgrades.erb"),
     require       => Package['unattended-upgrades'],
     notify_update => $notify_update,
   }
 
   apt::conf { 'periodic':
     priority      => 10,
     content       => template("${module_name}/periodic.erb"),
     require       => Package['unattended-upgrades'],
     notify_update => $notify_update,
   }
 
   apt::conf { 'auto-upgrades':
     ensure        => absent,
     priority      => 20,
     require       => Package['unattended-upgrades'],
     notify_update => $notify_update,
   }
   apt::conf { 'options':
     priority      => 10,
     content       => template("${module_name}/options.erb"),
     require       => Package['unattended-upgrades'],
     notify_update => $notify_update,
   }
-
 }
diff --git a/manifests/params.pp b/manifests/params.pp
index 4bb14c7..9e228d6 100644
--- a/manifests/params.pp
+++ b/manifests/params.pp
@@ -1,66 +1,67 @@
 #
 class unattended_upgrades::params {
-
   if $facts['os']['family'] != 'Debian' {
     fail('This module only works on Debian or derivatives like Ubuntu')
   }
 
   $default_auto                 = { 'fix_interrupted_dpkg' => true, 'remove' => true, 'reboot' => false, 'clean' => 0, 'reboot_time' => 'now', }
   $default_mail                 = { 'only_on_error'        => true, }
   $default_backup               = { 'archive_interval'     => 0, 'level'     => 3, }
   $default_age                  = { 'min'                  => 2, 'max'       => 0, }
   $default_upgradeable_packages = { 'download_only'        => 0, 'debdelta'  => 1, }
-  $default_options              = { 'force_confdef'        => true,
-                                    'force_confold'        => true,
-                                    'force_confnew'        => false,
-                                    'force_confmiss'       => false, }
+  $default_options              = {
+    'force_confdef'        => true,
+    'force_confold'        => true,
+    'force_confnew'        => false,
+    'force_confmiss'       => false,
+  }
 
   case fact('lsbdistid') {
     'debian', 'raspbian': {
       case fact('lsbdistcodename') {
         'buster': {
           $legacy_origin      = false
           $origins            = [
             'origin=Debian,codename=${distro_codename},label=Debian', #lint:ignore:single_quote_string_with_variables
             'origin=Debian,codename=${distro_codename},label=Debian-Security', #lint:ignore:single_quote_string_with_variables
           ]
         }
         default: {
           $legacy_origin      = false
           $origins            = [
             'origin=Debian,codename=${distro_codename},label=Debian-Security', #lint:ignore:single_quote_string_with_variables
           ]
         }
       }
     }
     'ubuntu', 'neon': {
       # Ubuntu: https://ubuntu.com/about/release-cycle and https://wiki.ubuntu.com/Releases
       $legacy_origin      = true
       $origins            = [
         '${distro_id}:${distro_codename}', #lint:ignore:single_quote_string_with_variables
         '${distro_id}:${distro_codename}-security', #lint:ignore:single_quote_string_with_variables
       ]
     }
     'LinuxMint': {
       case fact('lsbmajdistrelease') {
         # Linux Mint 18* is based on Ubuntu 16.04
         '18': {
           $legacy_origin      = true
           $origins            = [
             'Ubuntu:xenial-security',
           ]
         }
         default: {
           $legacy_origin      = true
           $origins            = [
             '${distro_id}:${distro_codename}-security', #lint:ignore:single_quote_string_with_variables
           ]
         }
       }
     }
     default: {
       $legacy_origin = undef
       $origins       = undef
     }
   }
 }