diff --git a/manifests/conf.pp b/manifests/conf.pp
index 8017f54..89b84a7 100644
--- a/manifests/conf.pp
+++ b/manifests/conf.pp
@@ -1,124 +1,124 @@
 # Define: sudo::conf
 #
 # This module manages sudo configurations
 #
 # Parameters:
 #   [*ensure*]
 #     Ensure if present or absent.
 #     Default: present
 #
 #   [*priority*]
 #     Prefix file name with $priority
 #     Default: 10
 #
 #   [*content*]
 #     Content of configuration snippet.
 #     Default: undef
 #
 #   [*source*]
 #     Source of configuration snippet.
 #     Default: undef
 #
 #   [*sudo_config_dir*]
 #     Where to place configuration snippets.
 #     Only set this, if your platform is not supported or
 #     you know, what you're doing.
 #     Default: auto-set, platform specific
 #
 # Actions:
 #   Installs sudo configuration snippets
 #
 # Requires:
 #   Class sudo
 #
 # Sample Usage:
 #   sudo::conf { 'admins':
 #     source => 'puppet:///files/etc/sudoers.d/admins',
 #   }
 #
 # [Remember: No empty lines between comments and class definition]
 define sudo::conf(
   $ensure           = present,
   $priority         = 10,
   $content          = undef,
   $source           = undef,
   $template         = undef,
   $sudo_config_dir  = undef,
   $sudo_file_name   = undef,
   $sudo_syntax_path = '/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin'
   ) {
 
     include ::sudo
 
   # Hack to allow the user to set the config_dir from the
   # sudo::config parameter, but default to $sudo::params::config_dir
   # if it is not provided. $sudo::params isn't included before
   # the parameters are loaded in.
   $sudo_config_dir_real = $sudo_config_dir ? {
     undef            => $sudo::config_dir,
     $sudo_config_dir => $sudo_config_dir
   }
 
   # sudo skip file name that contain a "."
   $dname = regsubst($name, '\.', '-', 'G')
 
   if size("x${priority}") == 2 {
     $priority_real = "0${priority}"
   } else {
     $priority_real = $priority
   }
 
   # build current file name with path
   if $sudo_file_name != undef {
     $cur_file = "${sudo_config_dir_real}/${sudo_file_name}"
   } else {
     $cur_file = "${sudo_config_dir_real}/${priority_real}_${dname}"
   }
 
   # replace whitespace in file name
   $cur_file_real = regsubst($cur_file, '\s+', '_', 'G')
 
   Class['sudo'] -> Sudo::Conf[$name]
 
   if $::osfamily == 'RedHat' {
     if (versioncmp($::sudoversion, '1.7.2p1') < 0) {
       warning("Found sudo with version ${::sudoversion}, but at least version 1.7.2p1 is required!")
     }
   }
 
   if $content != undef {
-    if is_array($content) {
+    if $content =~ Array {
       $lines = join($content, "\n")
       $content_real = "# This file is managed by Puppet; changes may be overwritten\n${lines}\n"
     } else {
       $content_real = "# This file is managed by Puppet; changes may be overwritten\n${content}\n"
     }
   } elsif $template != undef {
     $content_real = template($template)
   } else {
     $content_real = undef
   }
 
   if $ensure == 'present' {
     $notify_real = Exec["sudo-syntax-check for file ${cur_file}"]
   } else {
     $notify_real = undef
   }
 
   file { "${priority_real}_${dname}":
     ensure  => $ensure,
     path    => $cur_file_real,
     owner   => 'root',
     group   => $sudo::params::config_file_group,
     mode    => '0440',
     source  => $source,
     content => $content_real,
     notify  => $notify_real,
   }
 
   exec {"sudo-syntax-check for file ${cur_file}":
     command     => "visudo -c -f '${cur_file_real}' || ( rm -f '${cur_file_real}' && exit 1)",
     refreshonly => true,
     path        => $sudo_syntax_path,
   }
 }
diff --git a/manifests/configs.pp b/manifests/configs.pp
index 5b49de0..cbf2f82 100644
--- a/manifests/configs.pp
+++ b/manifests/configs.pp
@@ -1,27 +1,26 @@
 # Class: sudo::configs
 #
 # This class enables support for a full hiera based sudoers configuration.
 # Hiera functionality is auto enabled during the initial sudo module load;
 #   this class is not intended to be loaded directly.
 #
 # See the primary sudo module documentation for usage and examples.
 #
 class sudo::configs (
-    $configs_hash = {},
+    Hash $configs_hash = {},
   ){
 
-  validate_hash ( $configs_hash )
   # NOTE: hiera_hash does not work as expected in a parameterized class
   #   definition; so we call it here.
   #
   # http://docs.puppetlabs.com/hiera/1/puppet.html#limitations
   # https://tickets.puppetlabs.com/browse/HI-118
   #
   $configs = lookup('sudo::configs', Hash, {'strategy' => 'deep', 'merge_hash_arrays' => true}, $configs_hash)
 
   if !empty($configs) {
     create_resources('sudo::conf', $configs)
   }
 
 }
 
diff --git a/manifests/init.pp b/manifests/init.pp
index 27d5dfc..cb43754 100644
--- a/manifests/init.pp
+++ b/manifests/init.pp
@@ -1,176 +1,174 @@
 # Class: sudo
 #
 # This module manages sudo
 #
 # Parameters:
 #   [*ensure*]
 #     Ensure if present or absent.
 #     Default: present
 #
 #   [*package*]
 #     Name of the package.
 #     Only set this, if your platform is not supported or you know,
 #     what you're doing.
 #     Default: auto-set, platform specific
 #
 #   [*package_ensure*]
 #     Allows you to ensure a particular version of a package
 #     Default: present / lastest for RHEL < 5.5
 #
 #   [*package_source*]
 #     Where to find the package.  Only set this on AIX (required) and
 #     Solaris (required) or if your platform is not supported or you
 #     know, what you're doing.
 #
 #     The default for aix is the perzl sudo package. For solaris 10 we
 #     use the official www.sudo.ws binary package.
 #
 #     Default: AIX: perzl.org
 #              Solaris: www.sudo.ws
 #
 #   [*package_admin_file*]
 #     Where to find a Solaris 10 package admin file for
 #     an unattended installation. We do not supply a default file, so
 #     this has to be staged separately
 #
 #     Only set this on Solaris 10 (required)
 #     Default: /var/sadm/install/admin/puppet
 #
 #   [*purge*]
 #     Whether or not to purge sudoers.d directory
 #     Default: true
 #
 #   [*purge_ignore*]
 #     Files to exclude from purging in sudoers.d directory
 #     Default: undef
 #
 #   [*config_file*]
 #     Main configuration file.
 #     Only set this, if your platform is not supported or you know,
 #     what you're doing.
 #     Default: auto-set, platform specific
 #
 #   [*config_dir*]
 #     Main directory containing sudo snippets, imported via
 #     includedir stanza in sudoers file
 #     Default: auto-set, platform specific
 #
 #   [*extra_include_dirs*]
 #     Array of additional directories containing sudo snippets
 #     Default: undef
 #
 #   [*content*]
 #     Alternate content file location
 #     Only set this, if your platform is not supported or you know,
 #     what you're doing.
 #     Default: auto-set, platform specific
 #
 #   [*ldap_enable*]
 #     Enable ldap support on the package
 #     Default: false
 #
 # Actions:
 #   Installs sudo package and checks the state of sudoers file and
 #   sudoers.d directory.
 #
 # Requires:
 #   Nothing
 #
 # Sample Usage:
 #   class { 'sudo': }
 #
 # [Remember: No empty lines between comments and class definition]
 class sudo(
-  $enable              = true,
-  $package             = $sudo::params::package,
-  $package_ldap        = $sudo::params::package_ldap,
-  $package_ensure      = $sudo::params::package_ensure,
-  $package_source      = $sudo::params::package_source,
-  $package_admin_file  = $sudo::params::package_admin_file,
-  $purge               = true,
-  $purge_ignore        = undef,
-  $config_file         = $sudo::params::config_file,
-  $config_file_replace = true,
-  $config_dir          = $sudo::params::config_dir,
-  $extra_include_dirs  = undef,
-  $content             = $sudo::params::content,
-  $ldap_enable         = false,
+  Boolean                  $enable              = true,
+  String                   $package             = $sudo::params::package,
+  String                   $package_ldap        = $sudo::params::package_ldap,
+  String                   $package_ensure      = $sudo::params::package_ensure,
+  Optional[String]         $package_source      = $sudo::params::package_source,
+  Optional[String]         $package_admin_file  = $sudo::params::package_admin_file,
+  Boolean                  $purge               = true,
+  Optional[String]         $purge_ignore        = undef,
+  String                   $config_file         = $sudo::params::config_file,
+  Boolean                  $config_file_replace = true,
+  String                   $config_dir          = $sudo::params::config_dir,
+  Optional[Array[String]]  $extra_include_dirs  = undef,
+  String                   $content             = $sudo::params::content,
+  Boolean                  $ldap_enable         = false,
 ) inherits sudo::params {
 
 
-  validate_bool($enable)
   case $enable {
     true: {
       $dir_ensure  = 'directory'
       $file_ensure = 'present'
     }
     false: {
       $dir_ensure  = 'absent'
       $file_ensure = 'absent'
     }
     default: { fail('no $enable is set') }
   }
 
-  validate_bool($ldap_enable)
   case $ldap_enable {
     true: {
       if $package_ldap == undef {
         fail('on your os ldap support for sudo is not yet supported')
       }
       $package_real = $package_ldap
     }
     false: {
       $package_real = $package
     }
     default: { fail('no $ldap_enable is set') }
   }
 
 
   class { '::sudo::package':
     package            => $package_real,
     package_ensure     => $package_ensure,
     package_source     => $package_source,
     package_admin_file => $package_admin_file,
     ldap_enable        => $ldap_enable,
   }
 
   file { $config_file:
     ensure  => $file_ensure,
     owner   => 'root',
     group   => $sudo::params::config_file_group,
     mode    => '0440',
     replace => $config_file_replace,
     content => template($content),
     require => Class['sudo::package'],
   }
 
   file { $config_dir:
     ensure  => $dir_ensure,
     owner   => 'root',
     group   => $sudo::params::config_file_group,
     mode    => '0550',
     recurse => $purge,
     purge   => $purge,
     ignore  => $purge_ignore,
     require => Class['sudo::package'],
   }
 
   # Load the Hiera based sudoer configuration (if enabled and present)
   #
   # NOTE: We must use 'include' here to avoid circular dependencies with
   #     sudo::conf
   #
   # NOTE: There is no way to detect the existence of hiera. This automatic
   #   functionality is therefore made exclusive to Puppet 3+ (hiera is embedded)
   #   in order to preserve backwards compatibility.
   #
   #   http://projects.puppetlabs.com/issues/12345
   #
   if (versioncmp($::puppetversion, '3') != -1) {
     include '::sudo::configs'
   }
 
   anchor { 'sudo::begin': }
   -> Class['sudo::package']
   -> anchor { 'sudo::end': }
 }