diff --git a/manifests/icinga2.pp b/manifests/icinga2.pp
new file mode 100644
index 0000000..10c980e
--- /dev/null
+++ b/manifests/icinga2.pp
@@ -0,0 +1,12 @@
+# Icinga2 configuration
+class profile::icinga2 {
+  $icinga2_role = hiera('icinga2::role')
+
+  include profile::icinga2::apt_config
+
+  case $icinga2_role {
+    'agent':  { include profile::icinga2::agent }
+    'master': { include profile::icinga2::master }
+    default:  { fail("Unknown icinga2::role: ${icinga2_role}") }
+  }
+}
diff --git a/manifests/icinga2/agent.pp b/manifests/icinga2/agent.pp
index c54f3b8..03fa72d 100644
--- a/manifests/icinga2/agent.pp
+++ b/manifests/icinga2/agent.pp
@@ -1,54 +1,52 @@
 # Icinga2 agent configuration
 class profile::icinga2::agent {
   $features = hiera('icinga2::features')
   $icinga2_network = hiera('icinga2::network')
   $icinga2_host_vars = hiera_hash('icinga2::host::vars')
 
   $parent_zone = hiera('icinga2::parent_zone')
   $parent_endpoints = hiera('icinga2::parent_endpoints')
 
-  include profile::icinga2::apt_config
-
   class {'::icinga2':
     confd    => false,
     features => $features,
   }
 
   class { '::icinga2::feature::api':
     accept_config   => true,
     accept_commands => true,
     zones           => {
       'ZoneName' => {
         endpoints => ['NodeName'],
         parent    => $parent_zone,
       },
     },
   }
 
   create_resources('::icinga2::object::endpoint', $parent_endpoints)
   ::icinga2::object::zone {$parent_zone:
     endpoints => keys($parent_endpoints),
   }
 
   @@::icinga2::object::endpoint {$::fqdn:
     target => "/etc/icinga2/zones.d/${parent_zone}/${::fqdn}.conf",
   }
 
   @@::icinga2::object::zone {$::fqdn:
     endpoints => [$::fqdn],
     parent    => $parent_zone,
     target    => "/etc/icinga2/zones.d/${parent_zone}/${::fqdn}.conf",
   }
 
   @@::icinga2::object::host {$::fqdn:
     address       => ip_for_network($icinga2_network),
     display_name  => $::fqdn,
     check_command => 'hostalive',
     vars          => $icinga2_host_vars,
     target        => "/etc/icinga2/zones.d/${parent_zone}/${::fqdn}.conf",
   }
 
   icinga2::object::zone { 'global-templates':
     global => true,
   }
 }
diff --git a/manifests/icinga2/master.pp b/manifests/icinga2/master.pp
index b08d3c5..9fe90a4 100644
--- a/manifests/icinga2/master.pp
+++ b/manifests/icinga2/master.pp
@@ -1,90 +1,89 @@
 # An icinga master host
 class profile::icinga2::master {
   $zonename = hiera('icinga2::master::zonename')
   $features = hiera('icinga2::features')
   $icinga2_network = hiera('icinga2::network')
 
   $icinga2_host_vars = hiera_hash('icinga2::host::vars')
 
   $icinga2_db_username = hiera('icinga2::master::db::username')
   $icinga2_db_password = hiera('icinga2::master::db::password')
   $icinga2_db_database = hiera('icinga2::master::db::database')
 
-  include profile::icinga2::apt_config
   include profile::icinga2::objects
 
   include ::postgresql::server
 
   ::postgresql::server::db {$icinga2_db_database:
     user     => $icinga2_db_username,
     password => postgresql_password($icinga2_db_username, $icinga2_db_password)
   }
 
   class {'::icinga2':
     confd     => true,
     features  => $features,
     constants => {
       'ZoneName' => $zonename,
     },
   }
 
   class { '::icinga2::feature::api':
     accept_commands => true,
     zones           => {},
     endpoints       => {},
   }
 
   class { '::icinga2::feature::idopgsql':
     user          => $icinga2_db_username,
     password      => $icinga2_db_password,
     database      => $icinga2_db_database,
     import_schema => true,
     require       => Postgresql::Server::Db[$icinga2_db_database],
   }
 
   @@::icinga2::object::endpoint {$::fqdn:
     target => "/etc/icinga2/zones.d/${zonename}/${::fqdn}.conf",
   }
 
   @@::icinga2::object::zone {$zonename:
     endpoints => [$::fqdn],
     target    => "/etc/icinga2/zones.d/${zonename}/${::fqdn}.conf",
   }
 
   @@::icinga2::object::host {$::fqdn:
     address       => ip_for_network($icinga2_network),
     display_name  => $::fqdn,
     check_command => 'hostalive',
     vars          => $icinga2_host_vars,
     target        => "/etc/icinga2/zones.d/${zonename}/${::fqdn}.conf",
   }
 
   ::Icinga2::Object::Host <<| |>>
   ::Icinga2::Object::Endpoint <<| |>>
   ::Icinga2::Object::Zone <<| |>>
 
   ::icinga2::object::zone { 'global-templates':
     global => true,
   }
 
   file {[
     '/etc/icinga2/zones.d/global-templates',
     "/etc/icinga2/zones.d/${zonename}",
   ]:
     ensure => directory,
     owner  => 'nagios',
     group  => 'nagios',
     mode   => '0755',
     tag    => 'icinga2::config::file',
   }
 
   file {'/etc/icinga2/conf.d':
     ensure  => directory,
     owner   => 'nagios',
     group   => 'nagios',
     mode    => '0755',
     purge   => true,
     recurse => true,
     tag     => 'icinga2::config::file',
   }
 }